Leadwerks – A Great Indie Engine

S.Richmond — Sun, 08 Nov 2009 05:00:51 +0000

Last year I decided I’d bite the bullet and learn C++ with the end-goal of being able to finally design and build my own applications and games. So I went and got the fantastic C++ video tutorial library from 3D Buzz, which I strongly recommend any new C++ video game developer go through – They take you right form start to finish. All the way from an ASCII rogue-like game to a sprite-based game. Furthermore, its all designed in pretty OO.

As I began the 6th and last series of the 3D Buzz tutorials – Creating a 3D OpenGL engine – I decided I’d like to focus less on the core mathematics of displaying pixels and more on the creation and design of actual games. I’m not a very good mathematician after-all, and getting into that kind of stuff requires low-level efficient code. Code I really don’t have the skill to write just yet.

So I started looking around for graphics engine libraries that’ll allow me to focus on the game itself. There are a startlingly huge number of graphics engines out there, both free and not, and while I went through quite a damn few I want to talk about just one.

Leadwerks

http://www.leadwerks.com

I’ve been using the Leadwerks engine for about 6 months now and I’m loving it. Why?

The Engine – Built from the ground up to be a user-friendly and complete package. Modelled after the Crytek Crysis engine, it has all the features one could possibly need for both a wide-open game (Like Crysis) or an in-doors game, complete with a real-time sandbox editor. I think what I love most is that it is a very OO-centric engine. The code is just so clean and easy to understand – The huge plus for someone starting out like me.
Documentation - The documentation is all built up on a very-well organised and clean wiki, which you can freely browse for yourself. Josh, the creator, has made video tutorials for almost all aspects of the engine. This means you can pretty much just jump in, follow the tutorials, and you WILL have a running game in under a day.
Community - The Leadwerks forums, also freely available, is a small but very helpful community. Josh, the creator, is often on there as well. You’ll find that any questions will be answered in under a day.
Cost - One of the more problematic issues about Leadwerks. The cost is $100US upfront. Meaning you need to dish out early to really start. On the other hand, once you pay the initial fee you’re done. You get the engine for life, including any updates, and you can do whatever you want with your application. Which makes this engine one of the cheapest going around.

All in all, Leadwerks seems to be the perfect engine for someone who has a basic understanding of OO C++ and would like to dive into game development. Although the initial $100US fee can be a bit daunting for some, I highly recommend it.

VBScript – Map Printers Based On IP / VLAN ID

S.Richmond — Thu, 13 Aug 2009 08:24:07 +0000

Little script I made. Pretty self explanatory. Works real well.

' ****************************************************
'                 PRINTER MAPPER v0.9
' ****************************************************
' This script will map a network printer at user
' logon based on what floor the computer is currently
' on. This is done by viewing the VLAN ID found in
' the IP address field.
'
' Scott T Richmond,
'  IBM Australia.
'  August 2009.
'
' TODO:
'  - Turn off all reporting.
'  - Error checking.
'
' Notes:
'  - Setting default printer is simple, but no way
'    to determine which one to set automatically so
'    not used.
'    objNetwork.SetDefaultPrinter "\\PRINTER_NAME"
' ****************************************************

' ****************************************************
'                    Compile Options
' ****************************************************
' Force variables to be explicitly defined or die:
Option Explicit
' Continue script dispite any errors:
On Error Resume Next
 
' ****************************************************
'                   Define Variables
' ****************************************************
dim VLAN19
dim VLAN22
dim VLAN23
dim VLAN24
dim VLAN25
dim VLAN26
dim VLAN27
dim WIFI(2)
dim IPArray(3)
dim objWMIService
dim objNetwork
dim IPConfigSet
dim IPConfig
dim splitIP
dim octet
 
' ****************************************************
'                    Set Variables
' ****************************************************
VLAN19 = "139"
VLAN22 = "145"
VLAN23 = "147"
VLAN24 = "149"
VLAN25 = "151"
VLAN26 = "153"
VLAN27 = "155"
WIFI(0) = "162"
WIFI(1) = "184"
WIFI(2) = "185"
Set objNetwork = CreateObject("WScript.Network")
Set objWMIService = GetObject("winmgmts:\\" & "." & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery ("Select IPAddress from Win32_NetworkAdapterConfiguration ")
 
' ****************************************************
'              Find and Parse Primary IP
' ****************************************************
' Primary IP is found by iterating through all interfaces
' and finding the best match for the LAN network IP.
' The code below discards ones that are:
'  - NULL.
'  - Anything other than a first IP octet of 10.
'  - Or corresponds to the WiFi VLAN IDs.
For Each IPConfig in IPConfigSet
    If Not IsNull(IPConfig.IPAddress) Then
       splitIP = Split(IPConfig.IPAddress(0), ".", -1, 1)
       If splitIP(0) = "10" Then
          If splitIP(2) = WIFI(0) or _
             splitIP(2) = WIFI(1) or _
             splitIP(2) = WIFI(2) Then
             WScript.Echo "Wi-fi connection found. Looking for LAN IP..."
          Else
             For octet=0 to 3
                 IPArray(octet) = splitIP(octet)
             Next
          End If
       End if
    End If
Next
 
' ****************************************************
'              Perform Work Based On VLAN
' ****************************************************
' Looks at third octet of the IP and determines what VLAN
' ID the IP address belongs to, then applies correct
' printer configuration.
If IPArray(0) <> "10" Then
  WScript.Echo "Invalid IP. Not in the 10/8 network range."
  ElseIF IPArray(2) = VLAN19 Then
     WScript.Echo "IP is in VLAN 19. Mapping L19 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L19UtilRmE-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L19UtilRmE-XerBW1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L19UtilRmW-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L19UtilRmW-HPPlot1"
  ElseIF IPArray(2) = VLAN22 Then
     WScript.Echo "IP is in VLAN 22. Mapping L22 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L22UtilRm-XerCol1"
  ElseIF IPArray(2) = VLAN23 Then
     WScript.Echo "IP is in VLAN 23. Mapping L23 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L23NthWest-XerBW1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L23UtilRmE-XerCol1"
  ElseIF IPArray(2) = VLAN24 Then
     WScript.Echo "IP is in VLAN 24. Mapping L24 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L24UtilRmW-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L24UtilRmE-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L24UtilRmW-HPPlot2"
  ElseIF IPArray(2) = VLAN25 Then
     WScript.Echo "IP is in VLAN 25. Mapping L25 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L25UtilRmE-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L25UtilRmE-XerBW1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L25UtilRmW-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L25UtilRmW-XerBW1"
  ElseIF IPArray(2) = VLAN26 Then
     WScript.Echo "IP is in VLAN 26. Mapping L26 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L26UtilRmE-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L26UtilRmW-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L26NthEast-XerCol1"
     ' Printer below is a secure printer and should not be automatically installed.
     'objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L26Cent-XerCol-1"
  ElseIF IPArray(2) = VLAN27 Then
     WScript.Echo "IP is in VLAN 27. Mapping L27 printers..."
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L27West-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L27UtilRm2E-XerCol1"
     objNetwork.AddWindowsPrinterConnection "\\PRINTSVR\L27UtilRm1E-XerCol1"
  Else
     WScript.Echo "Unknown VLAN."
End If
 
WScript.Quit
' End of VBScript

SrichNET » Programming

Leadwerks – A Great Indie Engine

Leadwerks

VBScript – Map Printers Based On IP / VLAN ID